2 files changed, 89 insertions, 1 deletions

diff --git a/Biz/Dev/Configuration.nix b/Biz/Dev/Configuration.nix
index 24293cf..13be1be 100644
--- a/Biz/Dev/Configuration.nix
+++ b/Biz/Dev/Configuration.nix
@@ -8,6 +8,7 @@ let
     jellyfin = 8096;
     httpdev = { from = 8000; to = 8099; };
     devallocHost = 8095;
+    hoogle = 8008;
   };
 in {
   networking = {
@@ -109,6 +110,15 @@ in {
   };
 
   services = {
+    my-hoogle = {
+      enable = true;
+      port = ports.hoogle;
+      home = "//hoogle.simatime.com";
+      packages = import ../Bild/Deps/Haskell.nix;
+      haskellPackages = pkgs.haskell.packages.ghc865;
+      host = "0.0.0.0";
+    };
+
     pcscd.enable = true;
     logind = {
       lidSwitch = "ignore";
@@ -223,7 +233,6 @@ in {
     nixos.enable = true;
   };
 
-
   nix = {
     autoOptimiseStore = true;
     buildCores = 0; # use all available cores
diff --git a/Biz/Dev/Hoogle.nix b/Biz/Dev/Hoogle.nix
new file mode 100644
index 0000000..13a5bda
--- /dev/null
+++ b/Biz/Dev/Hoogle.nix
@@ -0,0 +1,79 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.services.my-hoogle;
+
+  hoogleEnv = pkgs.buildEnv {
+    name = "hoogle";
+    paths = [ (cfg.haskellPackages.ghcWithHoogle cfg.packages) ];
+  };
+
+in {
+
+  options.services.my-hoogle = {
+    enable = mkEnableOption "Haskell documentation server";
+
+    port = mkOption {
+      type = types.int;
+      default = 8080;
+      description = ''
+        Port number Hoogle will be listening to.
+      '';
+    };
+
+    packages = mkOption {
+      default = hp: [];
+      defaultText = "hp: []";
+      example = "hp: with hp; [ text lens ]";
+      description = ''
+        The Haskell packages to generate documentation for.
+
+        The option value is a function that takes the package set specified in
+        the <varname>haskellPackages</varname> option as its sole parameter and
+        returns a list of packages.
+      '';
+    };
+
+    haskellPackages = mkOption {
+      description = "Which haskell package set to use.";
+      default = pkgs.haskellPackages;
+      defaultText = "pkgs.haskellPackages";
+    };
+
+    home = mkOption {
+      type = types.str;
+      description = "Url for hoogle logo";
+      default = "https://hoogle.haskell.org";
+    };
+
+    host = mkOption {
+      type = types.str;
+      description = "Set the host to bind on.";
+      default = "127.0.0.1";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    systemd.services.hoogle = {
+      description = "Haskell documentation server";
+
+      wantedBy = [ "multi-user.target" ];
+
+      serviceConfig = {
+        Restart = "always";
+        ExecStart = ''${hoogleEnv}/bin/hoogle server --local --port ${toString cfg.port} --home ${cfg.home} --host ${cfg.host}'';
+
+        DynamicUser = true;
+
+        ProtectHome = true;
+
+        RuntimeDirectory = "hoogle";
+        WorkingDirectory = "%t/hoogle";
+      };
+    };
+  };
+
+}