From f4b8c0df041b063c0b47d2ec6c818a9c202fd833 Mon Sep 17 00:00:00 2001
From: Ben Sima <ben@bsima.me>
Date: Wed, 15 Apr 2020 09:54:10 -0700
Subject: Re-namespacing

Moving away from the DNS-driven namespacing toward more condensed names,
mostly because I don't like typing so much.
---
 Hero/Service.nix | 76 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 Hero/Service.nix

(limited to 'Hero/Service.nix')

diff --git a/Hero/Service.nix b/Hero/Service.nix
new file mode 100644
index 0000000..f0f4227
--- /dev/null
+++ b/Hero/Service.nix
@@ -0,0 +1,76 @@
+{ options
+, lib
+, config
+, pkgs
+, modulesPath
+}:
+
+let
+  cfg = config.services.herocomics;
+in
+{
+  options.services.herocomics = {
+    enable = lib.mkEnableOption "Enable the herocomics service";
+    port = lib.mkOption {
+      type = lib.types.int;
+      default = 3000;
+      description = ''
+        The port on which herocomics-server will listen for incoming HTTP traffic.
+      '';
+    };
+    server = lib.mkOption {
+      type = lib.types.package;
+      description = "herocomics-server package to use";
+    };
+    client = lib.mkOption {
+      type = lib.types.package;
+      description = "herocomics-client package to use";
+    };
+    domain = lib.mkOption {
+      type = lib.types.str;
+      default = "herocomics.app";
+      description = ''
+        Domain on which to bind herocomics-server. This is passed
+        to services.nginx.virtualHosts.<name> directly.
+      '';
+    };
+  };
+  config = lib.mkIf cfg.enable {
+    systemd.services.herocomics = {
+      path = [ cfg.server ];
+      wantedBy = [ "multi-user.target" ];
+      script = ''
+        ${cfg.server}/bin/mmc
+      '';
+      description = ''
+        Hero Comics app server
+      '';
+      serviceConfig = {
+        KillSignal = "INT";
+        Environment = [
+          "HERO_CLIENT=${cfg.client}/static"
+          "HERO_PORT=${toString cfg.port}"
+        ];
+        Type = "simple";
+        Restart = "on-abort";
+        RestartSec = "1";
+      };
+    };
+    services.nginx = {
+       enable = cfg.enable;
+       recommendedGzipSettings = true;
+       recommendedOptimisation = true;
+       recommendedProxySettings = true;
+       recommendedTlsSettings = true;
+       virtualHosts = {
+         "${cfg.domain}" = {
+           forceSSL = true;
+           enableACME = true;
+           locations."/" = {
+             proxyPass = "http://localhost:${toString cfg.port}";
+           };
+         };
+       };
+     };
+  };
+}
-- 
cgit v1.2.3