_self: super:

with import ./Constants.nix;
let
  buildCabal = sel: name: sel.callCabal2nix name super.sources.${name} { };
  buildCabalSubdir = sel:
    { name, src ? super.sources.${name}, subdir ? name }:
    sel.callCabal2nix name (src + "/${subdir}") { };
in rec {
  haskell = super.haskell // {
    packages = super.haskell.packages // {
      "${ghcCompiler}" = super.haskell.packages."${ghcCompiler}".override
        (_old: {
          overrides = with super.pkgs.haskell.lib;
            sel: sup:
            super.overridePinnedDeps (buildCabal sel) // {
              acid-state =
                dontCheck sup.acid-state; # mac: "too many open files"
              clay = doJailbreak sup.clay;
              envy = doJailbreak sup.envy;
              fast-tags =
                sup.fast-tags.overrideAttrs (old: old // { patches = [ ]; });
              generic-data = dontCheck
                sup.generic-data; # https://github.com/Lysxia/generic-data/issues/56
              readable =
                doJailbreak sup.readable; # why is this even being built?
              servant-auth = doJailbreak (buildCabalSubdir sel {
                name = "servant-auth";
                subdir = "servant-auth/servant-auth";
              });
              servant-server = doJailbreak sup.servant-server;
              stripe-core = doJailbreak sup.stripe-core;
              stripe-haskell = dontCheck sup.stripe-haskell;
              stripe-http-client =
                doJailbreak (dontCheck sup.stripe-http-client);
              temporary = dontCheck sup.temporary;
              wai-middleware-metrics = dontCheck sup.wai-middleware-metrics;
            };
        });
    };
  };

  python3 = super.python3.override {
    packageOverrides = _: pysuper:
      with pysuper.pkgs.python3Packages; {
        exllama = callPackage ./Deps/exllama.nix {
          cudaPackages = super.pkgs.cudaPackages_11_7;
        };
        interegular = callPackage ./Deps/interegular.nix { };
        outlines = callPackage ./Deps/outlines.nix { };
        perscache = callPackage ./Deps/perscache.nix { };
      };
  };

  python3Packages = python3.pkgs;

  autogen = super.callPackage ./Deps/autogen.nix { };

  guile = super.guile_3_0;

  guile-opengl = super.callPackage ./Deps/guile-opengl.nix { };
  # The libfive build is broken...
  #inspekt3d = super.callPackage ./Deps/inspekt3d.nix {};
  guix = super.pkgs.stdenv.mkDerivation rec {
    pname = "guix";
    name = "${pname}-${version}";
    version = super.sources.guix.version;
    src = super.sources.guix;
    buildInputs = with super.pkgs; [
      guile
      # guile-gcrypt
      # guile-sql
      # guile-zlib
      # guile-lzlib
      # guile-avahi
      # guile-git
      # guile-json
      gnutls
      gnumake
      sqlite
      libgcrypt
      gcc
    ];
  };

  llama-cpp = super.callPackage ./Deps/llama-cpp.nix { };

  nostr-rs-relay = super.callPackage ./Deps/nostr-rs-relay.nix { };
}