nixpkgs:

{  name  # the namespace
,  nick  # a short name, for the executable
,  deps  # deps get passed to the compilers
}:

with nixpkgs;

let
  nsToPath = ns: builtins.toString (builtins.replaceStrings ["."] ["/"] ns);
  pathToNs = p: builtins.replaceStrings ["/"] ["."] p;
  basePath = nsToPath name;
  apexPath = basePath + "/Apex"; # compiled with ghc
  aeroPath = basePath + "/Aero"; # compiled with ghcjs

  depsToPackageSet = packageSet: deps:
    map (s: builtins.getAttr s packageSet) deps;

  claySrc = pkgs.fetchFromGitHub {
    owner = "sebastiaanvisser";
    repo = "clay";
    rev = "cc7729b1b42a79e261091ff7835f7fc2a7ae3cee";
    sha256 = "1vd67976lvi5l4qq18zy6j44apynkl44ps04p8vwfx4gzr895dyp";
  };

  ghc865_ = pkgs.haskell.packages.ghc865.override (oldAttrs: {
    overrides = with pkgs.haskell.lib; self: super: {
      clay = self.callCabal2nix "clay" claySrc {};
      wai-middleware-metrics = dontCheck super.wai-middleware-metrics;
    };
  });

  ghc = ghc865_.ghcWithPackages (hp: depsToPackageSet hp
    (deps.both ++ deps.apex));

  # ghcjs-8.6.0.1
  ghcjs_ = pkgs.haskell.packages.ghcjs.override (oldAttrs: {
    overrides = with pkgs.haskell.lib; self: super: {
      clay = dontCheck (self.callCabal2nix "clay" claySrc {});
      http-types = dontCheck super.http-types;
      tasty-quickcheck = dontCheck super.tasty-quickcheck;
      scientific = dontCheck super.scientific; # takes forever
      servant = dontCheck super.servant;
      comonad = dontCheck super.comonad;
      QuickCheck = dontCheck super.QuickCheck;
    };
  });

  ghcjs = ghcjs_.ghcWithPackages (hp:
    depsToPackageSet hp (deps.both ++ deps.aero));

in {
  inherit ghc ghcjs;
  app = stdenv.mkDerivation {
    name = name;
    version = "0";
    src = ../../.; # this is the git root
    nativeBuildInputs = [
      ghc ghcjs guile
    ];
    strictDeps = true;
    buildPhase = ''
      #
      mkdir -p $out/{bin,static} ${basePath}
      #
      # compile with ghc
      #
      ${ghc}/bin/ghc -Werror -i. \
          --make ${apexPath}.hs \
          -main-is ${pathToNs apexPath} \
          -o $out/bin/${nick}
      #
      # compile with ghcjs
      #
      ${ghcjs}/bin/ghcjs -Werror -i. \
          --make ${aeroPath}.hs \
          -main-is ${pathToNs aeroPath} \
          -o ${aeroPath}
      #
      # optimize js output
      #
      ${pkgs.closurecompiler}/bin/closure-compiler \
          ${aeroPath}.jsexe/all.js > $out/static/${nick}.js
    '';
    # the install process was handled above
    installPhase = "exit 0";
  };
}