let
  nixpkgs-tar = builtins.fetchTarball (import ./nixpkgs.nix);
  nixpkgs = import "${nixpkgs-tar}" {};
  nixos = import "${nixpkgs-tar}/nixos";
  # TODO(bsima): buildNixOS should be split into multiple functions that each
  # return one thing, instead of a single function that returns multiple things
  biz = import ./biz.nix { inherit nixpkgs; };
  buildOS = import ./Com/Simatime/buildOS.nix nixos;
  nixos-mailserver = let ver = "v2.3.0"; in builtins.fetchTarball {
    url = "https://gitlab.com/simple-nixos-mailserver/nixos-mailserver/-/archive/${ver}/nixos-mailserver-${ver}.tar.gz";
    sha256 = "0lpz08qviccvpfws2nm83n7m2r8add2wvfg9bljx9yxx8107r919";
  };
in rec {
  # Cloud infrastructure, always online. Mostly for messaging-related
  # stuff.
  #
  Com.Simatime.Cloud = buildOS {
    enableVpn = true;
    ipAddress = "159.89.128.69";
    vpnRsaPrivateKeyFile = "/etc/tinc/rsa_key.priv";
    vpnEd25519PrivateKeyFile = "/etc/tinc/ed25519_key.priv";
    configuration = {
      imports = [
        ./Com/Simatime/packages.nix
        ./Com/Simatime/users.nix
        ./Com/Simatime/Cloud/chat.nix
        ./Com/Simatime/Cloud/git.nix
        ./Com/Simatime/Cloud/hardware.nix
        ./Com/Simatime/Cloud/mail.nix
        ./Com/Simatime/Cloud/networking.nix
        ./Com/Simatime/Cloud/web.nix
        ./Com/Simatime/Cloud/znc.nix
        nixos-mailserver
      ];
      networking.hostName = "simatime";
      networking.domain = "simatime.com";
    };
  };
  # Dev machine for work and building stuff.
  #
  Com.Simatime.Dev = buildOS {
    enableVpn = true;
    ipAddress = "69.181.254.154";
    configuration = {
      imports = [
        ./Com/Simatime/packages.nix
        ./Com/Simatime/users.nix
        ./Com/Simatime/Dev/configuration.nix
        ./Com/Simatime/Dev/hardware.nix
      ];
      networking.hostName = "lithium";
      networking.domain = "dev.simatime.com";
    };
  };
  # Serval is the production server for apps
  #
  Com.Simatime.Serval = buildOS {
    deps = { que-server = Run.Que.Server; };
    configuration = {
      imports = [
        ./Com/Simatime/packages.nix
        ./Com/Simatime/Serval/hardware.nix
        ./Com/Simatime/Serval/networking.nix
        ./Com/Simatime/Serval/configuration.nix
        ./Run/Que/service.nix
      ];
      networking.hostName = "serval";
      networking.domain = "serval.simatime.com";
      boot.enableContainers = true;
    };
  };
  # Haskell targets
  #
  Com.InfluencedByBooks.Server = biz.buildGhc Com/InfluencedByBooks/Server.hs;
  Com.InfluencedByBooks.Client = biz.buildGhcjs Com/InfluencedByBooks/Client.hs;
  Com.MusicMeetsComics.Server = biz.buildGhc Com/MusicMeetsComics/Server.hs;
  Com.MusicMeetsComics.Client = biz.buildGhcjs Com/MusicMeetsComics/Client.hs;
  Run.Que.Server = biz.buildGhc ./Run/Que/Server.hs;
  Run.Que.Website = biz.buildGhc ./Run/Que/Website.hs;
}