/*

nutin-madaj - cloud infrastructure server.

This serves the git repo, mailserver, znc bouncer, user sites, and so on.

Currently also used as a catch-all production/staging server, until I get real
stuff deployed.

*/

let
  nixpkgs = builtins.fetchTarball (import ../../pack/nixpkgs.nix);
  nixos-mailserver = builtins.fetchTarball {
    url = "https://gitlab.com/simple-nixos-mailserver/nixos-mailserver/-/archive/v2.2.1/nixos-mailserver-v2.2.1.tar.gz";
    sha256 = "03d49v8qnid9g9rha0wg2z6vic06mhp0b049s3whccn1axvs2zzx";
  };
  benKey =  "ssh-rsa AAAAB3NzaC1yc2EAAAADAQABAAABAQCiNB0iF9ClawNEizBtdYucqp1tAXXRbqvlPS6PFRrtiwSl+SJD29BCLgA5rLxcmFhBHZ/iId/En7GPFEzI/gMu071J7pUI4OcW0UVZju3GNc6ZEz/a6AD2u79JiXEDHfPEdmMqAe36kkaK0KJWSQP3xsFRwJ+8F8HHbSwoCLL+GJhBgAWHQLGfKesNrDacNljNDU3CgkEnDmu8QKuSzH2k1vrr69q2u2iMSAdiStDBAWEjN5nCVrm2XB2vmFLMtXpX2n8JI+znOGzRRDc8dNXejQeDMZGyV6jfVidEIX7vdgSydGjTRKcCLVAsKY3z0gYBZ8u8EUNujgcFBnnAvytj ben@neb";
  ibbPort = "3000";
  fathomPort = "3030";

in
import "${nixpkgs}/nixos" {
  system = "x86_64-linux";
  configuration = {
    imports = [
      ./hardware-configuration.nix
      ./networking.nix

      # configured modules
      ./git.nix
      ./mail.nix
      ./web.nix
      ./znc.nix

      # our custom modules
      ../../mode/ibb.nix
      ../../mode/fathom.nix

      # third party
      nixos-mailserver
    ];

    nixpkgs.config.allowUnfree = true;
    nixpkgs.overlays = [
      (import ../../pack/overlay.nix)
    ];

    networking.firewall.allowedTCPPorts = [ 22 80 443 ];

    virtualisation = {
      libvirtd.enable = true;
      docker.enable = true;
      virtualbox.guest.enable = true;
      virtualbox.host.enable = true;
      virtualbox.host.headless = false;
      virtualbox.host.addNetworkInterface = true;
    };

    # our custom apps
    services = {
      ibb = {
        enable = true;
        port = ibbPort;
      };
      # TODO: move this nginx config into mode/ibb.nix
      nginx.virtualHosts."influencedbybooks.com" = {
        forceSSL = true;
        enableACME = true;
        locations = {
          "/" = {
            proxyPass = "http://localhost:${ibbPort}";
          };
        };
      };

      fathom = {
        enable = true;
        port = fathomPort;
        dataDir = "/var/lib/fathom";
      };
      nginx.virtualHosts."stats.simatime.com" = {
        locations."/".proxyPass = "http://localhost:${fathomPort}";
        forceSSL = true;
        enableACME = true;
      };
    };

    boot.cleanTmpDir = true;
    networking.hostName = "simatime";
    networking.firewall.allowPing = true;
    services.openssh.enable = true;
    users.users.root.openssh.authorizedKeys.keys = [ benKey ];
  };
}