Re-namespace some stuff to Omni

I was getting confused about what is a product and what is internal
infrastructure; I think it is good to keep those things separate. So I moved a
bunch of stuff to an Omni namespace, actually most stuff went there. Only things
that are explicitly external products are still in the Biz namespace.

1 files changed, 33 insertions, 0 deletions

diff --git a/Omni/Bild/Functions.nix b/Omni/Bild/Functions.nix
new file mode 100644
index 0000000..8b87f86
--- /dev/null
+++ b/Omni/Bild/Functions.nix
@@ -0,0 +1,33 @@
+_: super: {
+  # Given a generic `builder`, will generate an attrset for all the packages
+  # pinned by `deps` with `builder` applied to the package. This attrset can
+  # then be merged with the rest of the packages in the set as part of an
+  # overlay or overrides.
+  overridePinnedDeps = builder:
+    super.lib.genAttrs (builtins.attrNames super.sources) builder;
+
+  # Modifies a derivation with our source and version, keeping super build
+  # rules. This will fail if build steps have changed, or if no build
+  # rules are available upstream.
+  overrideSource = depName:
+    if super ? "${depName}" && super.${depName} ? overrideAttrs then
+      super.${depName}.overrideAttrs (attrs:
+        attrs // rec {
+          version =
+            super.sources.${depName}.version or super.sources.${depName}.rev;
+          src = super.sources.${depName};
+        })
+    else
+      null;
+
+  # Simply override the 'src' attr on a drv. This is meant to be a simpler
+  # alternative to 'overrideSource' above. In an overlay, use it like:
+  #    mypkg = super.overrideSrc super.mypkg super.sources.mypkg;
+  overrideSrc = dep: src:
+    dep.overrideAttrs (attrs:
+      attrs // {
+        version = src.version or src.rev;
+        src = src;
+      });
+}
+