blob: b640a05a97c5d2e8fa2e3db829612bfb6155f417 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
|
{ nixpkgs ? import ./Bild/Nixpkgs.nix }:
with import ./Bild/Constants.nix;
let
# provided by .envrc
root = builtins.getEnv "BIZ_ROOT";
selectAttrs = deps: packageSet:
nixpkgs.lib.attrsets.attrVals deps packageSet;
# returns true if a is a subset of b, where a and b are attrsets
subset = a: b: builtins.all
(x: builtins.elem x b) a;
# 44 = lib.strings.stringLength "/nix/store/gia2r9mxhc900y1m97dlmr1g3rm3ich3-"
dropNixStore = s: nixpkgs.lib.strings.substring 44 (nixpkgs.lib.strings.stringLength s) s;
haskellDeps = import ./Bild/Deps/Haskell.nix;
ghcWith = nixpkgs.haskell.packages.${ghcCompiler}.ghcWithHoogle;
#mkGhcjsPackageSet = nixpkgs.haskell.packages.${ghcjsCompiler}.ghcWithPackages;
ghcPackageSetFull = ghcWith haskellDeps;
ghcPackageSetBild = ghcWith (hpkgs: with hpkgs; [
aeson async base bytestring conduit conduit-extra containers directory
docopt filepath process protolude rainbow regex-applicative split tasty
tasty-hunit tasty-quickcheck text
wai # can remove when removed from Biz.Log
]);
in rec {
inherit (nixpkgs) lib stdenv sources;
inherit ghcWith;
# a standard nix build for `bild` - this should be the only hand-written
# builder we need
bild = stdenv.mkDerivation {
name = "bild";
src = ../.;
nativeBuildInputs = [ ghcPackageSetBild ];
buildInputs = [ nixpkgs.makeWrapper ];
strictDeps = true;
buildPhase = ''
mkdir -p $out/bin $out/lib/ghc-${ghcPackageSetFull.version}
cp -r \
${ghcPackageSetFull}/lib/ghc-${ghcPackageSetFull.version}/package.conf.d \
$out/lib/ghc-${ghcPackageSetFull.version}
ghc \
-Werror \
-i. \
--make Biz/Bild.hs \
-main-is Biz.Bild \
-o $out/bin/bild
'';
installPhase = ''
wrapProgram $out/bin/bild \
--prefix PATH : ${lib.makeBinPath [ ghcPackageSetBild ]} \
--set GHC_PACKAGE_PATH \
$out/lib/ghc-${ghcPackageSetFull.version}/package.conf.d
'';
};
# wrapper around bild
runBildAnalyze = main: stdenv.mkDerivation rec {
name = "bild-analysis";
src = ../.;
USER = "nixbld";
HOSTNAME = "nix-sandbox";
# this is the default sandbox path where bild will be working:
BIZ_ROOT = "/build/biz";
# we need to remove the $src root because bild expects paths relative to the
# working directory:
MAIN = "." + lib.strings.removePrefix (toString src) (toString main);
buildPhase = ''
mkdir $out
${bild}/bin/bild --json "$MAIN" 1> $out/analysis.json \
2> >(tee -a $out/stderr >&2)
'';
installPhase = "exit 0";
};
# gather data needed for compiling by analyzing the main module
analyze = main:
builtins.head
(lib.trivial.importJSON
(runBildAnalyze main + "/analysis.json"));
ghc = main:
let
data = analyze main;
ghc = ghcWith (hp: selectAttrs data.langdeps hp);
module = lib.strings.concatStringsSep "." data.namespace.path;
in stdenv.mkDerivation {
name = module;
src = ../.;
nativeBuildInputs = [ ghc ] ++ selectAttrs data.sysdeps nixpkgs.pkgs;
strictDeps = true;
buildPhase = ''
set -eux
mkdir -p $out/bin
: compiling with ghc
${ghc}/bin/ghc \
-Werror \
-i. \
--make ${main} \
-main-is ${module} \
-o $out/bin/${data.out}
'';
# the install process was handled above
installPhase = "exit 0";
} // { env = ghc; };
#ghcjs = main:
# let
# data = analyze main;
# ghcjs = mkGhcjsPackageSet (hp: selectAttrs data.deps hp);
# in stdenv.mkDerivation {
# name = data.module;
# src = ../.;
# nativeBuildInputs = [ ghcjs ];
# strictDeps = true;
# buildPhase = ''
# mkdir -p $out/static
# # compile with ghcjs
# ${ghcjs}/bin/ghcjs \
# -Werror \
# -i. \
# --make ${main} \
# -main-is ${data.module} \
# -o ${data.out}
# # optimize js output
# ${nixpkgs.pkgs.closurecompiler}/bin/closure-compiler \
# ${data.out}/all.js > $out/static/${data.out}
# '';
# installPhase = "exit 0";
# } // { env = ghcjs; };
env = nixpkgs.pkgs.mkShell {
name = "bizdev";
buildInputs = with nixpkgs.pkgs; [
# this should just be dev tools
haskell.packages.${ghcCompiler}.apply-refact
bild
figlet
git
haskell.packages.${ghcCompiler}.fast-tags
hlint
lolcat
niv.niv
nixops
ormolu
python38Packages.black
python38Packages.pylint
shellcheck
wemux
] ++ lib.optional nixpkgs.stdenv.isLinux [
# scheme deps (i think these are broken on macOS)
guile
#inspekt3d
#libfive
];
shellHook = ". ${./Bild/ShellHook.sh}";
};
os = cfg: (nixpkgs.nixos (args: cfg)).toplevel;
pkgs = { inherit (nixpkgs) git; };
image = nixpkgs.pkgs.dockerTools.buildImage;
}
|
