Biz/Bot.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

{ options
, lib
, config
, pkgs
, ...
}:

let
  cfg = config.services.bizbot;
in
{
  options.services.bizbot = {
    enable = lib.mkEnableOption "Enable the bizbot service";
    package = lib.mkOption {
      type = lib.types.package;
      description = "bizbot package to use";
    };
    server = lib.mkOption {
      type = lib.types.str;
      description = "server address to connect to";
    };
    channel = lib.mkOption {
      type = lib.types.str;
      description = "channel to join";
    };
    dataDir = lib.mkOption {
      type = lib.types.str;
      description = "where bizbot will start it's ii tree";
    };
  };
  config = lib.mkIf cfg.enable {
    systemd.services = {
      "bizbot-${cfg.server}-${cfg.channel}-ii" = {
        wantedBy = [ "multi-user.target" ];
        path = [ pkgs.ii ];
        script = ''
          ${pkgs.ii}/bin/ii ${cfg.dataDir}/irc -s ${cfg.server} -p 6667 -n bizbot
        '';
        postStart = ''
          echo "/join ${cfg.channel}" > ${cfg.dataDir}/irc/${cfg.server}/in
        '';
        description = ''
          bizbot ii tree for ${cfg.server}/${cfg.channel}
        '';

      };
      "bizbot-${cfg.server}-${cfg.channel}" = {
        path = [ cfg.package ];
        wantedBy = [ "multi-user.target" ];
        after = [ "bizbot-${cfg.server}-${cfg.channel}-ii.service" ];
        script = ''
          tail -f ${cfg.dataDir}/irc/${cfg.server}/${cfg.channel}/out \
            | ${cfg.package}/bin/bizbot \
            | tee -a ${cfg.dataDir}/irc/${cfg.server}/${cfg.channel}/in
        '';
        description = ''
          bizbot for ${cfg.server}/${cfg.channel}
        '';
        serviceConfig = {
          KillSignal = "INT";
          Type = "simple";
          Restart = "on-abort";
          RestartSec = "1";
        };
      };
    };
  };
}