Biz/Que/Host.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

{ options, lib, config, ... }:

let cfg = config.services.que-server;
in {
  options.services.que-server = {
    enable = lib.mkEnableOption "Enable the que-server service";
    port = lib.mkOption {
      type = lib.types.int;
      default = 3000;
      description = ''
        The port on which que-server will listen for
        incoming HTTP traffic.
      '';
    };
    package = lib.mkOption {
      type = lib.types.package;
      description = "que-server package to use";
    };
  };
  config = lib.mkIf cfg.enable {
    systemd.services.que-server = {
      path = [ cfg.package ];
      wantedBy = [ "multi-user.target" ];
      script = ''
        ${cfg.package}/bin/que-server
      '';
      description = ''
        Que server
      '';
      serviceConfig = {
        Environment = [ "QUE_PORT=${toString cfg.port}" ];
        EnvironmentFile = "/run/que/env";
        KillSignal = "INT";
        Type = "simple";
        Restart = "always";
        RestartSec = "1";
      };
    };
  };
}