blob: d06b56714fd0430fdbc59993cbe2626d6c490df0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
{ options
, lib
, config
, pkgs
, modulesPath
}:
let
cfg = config.services.herocomics;
in
{
options.services.herocomics = {
enable = lib.mkEnableOption "Enable the herocomics service";
port = lib.mkOption {
type = lib.types.int;
default = 3000;
description = ''
The port on which herocomics-server will listen for incoming HTTP traffic.
'';
};
keep = lib.mkOption {
type = lib.types.path;
default = "/var/lib/hero";
description = "herocomics-server database directory";
};
host = lib.mkOption {
type = lib.types.package;
description = "herocomics-server package to use";
};
node = lib.mkOption {
type = lib.types.package;
description = "herocomics-client package to use";
};
skey = lib.mkOption {
type = lib.types.path;
default = "/run/hero/skey";
description = "where to store the signing key";
};
domain = lib.mkOption {
type = lib.types.str;
default = "herocomics.app";
description = ''
Domain on which to bind herocomics-server. This is passed
to services.nginx.virtualHosts.<name> directly.
'';
};
};
config = lib.mkIf cfg.enable {
systemd.services.herocomics = {
path = [ cfg.host ];
wantedBy = [ "multi-user.target" ];
script = ''
${cfg.host}/bin/mmc
'';
description = ''
Hero Comics app server
'';
serviceConfig = {
KillSignal = "INT";
Environment = [
"HERO_NODE=${cfg.node}/static"
"HERO_PORT=${toString cfg.port}"
"HERO_KEEP=${cfg.keep}"
"HERO_SKEY=/run/hero/skey"
];
Type = "simple";
Restart = "on-abort";
RestartSec = "1";
};
};
services.nginx = {
enable = cfg.enable;
recommendedGzipSettings = true;
recommendedOptimisation = true;
recommendedProxySettings = true;
recommendedTlsSettings = true;
virtualHosts = {
"${cfg.domain}" = {
forceSSL = true;
enableACME = true;
locations."/" = {
proxyPass = "http://localhost:${toString cfg.port}";
};
};
};
};
};
}
|
